Between a puff and a plume – A Chemical Engineer’s Notebook

In previous examples I used both Gaussian plume and puff models for continuous and instantaneous releases, respectively, but what about the in-between cases? It is more commonly the case for a leak from a process vessel to be a prolonged, but finitely long, release.

The guidance is to typically pick one or the other, depending upon the length of the release, or use a more complex model, e.g. the guidance in Lees¹ is

¹ Lees, Loss Prevention in the Process Industries, 15/199.

$u Δ t < 2 σ_{x}$	Use puff model
$2 σ_{x} < u Δ t < 5 σ_{x}$	Neither model entirely appropriate
$u Δ t > 5 σ_{x}$	Use plume model

Where u is the wind speed, Δt the duration of the release, and $σ_{x}$ is the downwind dispersion evaluated at $x = \frac{u Δ t}{2}$ .²

² These criteria drive one to using a plume model in most cases that are not “instantaneous”. Suppose $σ_{x} = α x^{β}$ then the criteria for a puff is $u Δ t < 2 α^{\frac{1}{1 - β}}$ which, for a class D release with windspeed of 2m/s works out to $Δ t < 5 \times 10^{- 16} s$ . The criteria for a plume is $u Δ t > 2 {(2.5 α)}^{\frac{1}{1 - β}}$ which works out to $Δ t > 5 \times 10^{- 11} s$ for the same situation. So for any release of appreciable duration it will be a plume.

An alternative approach is to evaluate the downwind dispersion at a particular point of interest x₁ and use the same criteria. This is much less strict than what Lees gives and is what I will do, it motivates investigating anything other than pure plume models.

One approach in this in-between zone is to try both and pick the most conservative. But that can lead to extremely conservative results. An alternative might be to take a page from more complex models, such as INTPUFF and SCIPUFF, and treat an intermediate release as a series of smaller puff releases.

Motivating example

Suppose a release from a process vessel, say a jet of gas issuing from a hole, we suppose the release is a constant rate of 1kg/s for 5s just for some nice round numbers. The release is at ground level and the ambient conditions are class D with a 2m/s windspeed. We have a point of interest 100m down-wind of the release, this could be an inhabited building or the fence-line.³

³ We are also implicitly assuming the release is neutrally buoyant, and so a Gaussian dispersion model would be appropriate.

m  = 1 #kg/s
Δt = 5 #s
h  = 0 #m
u  = 2 #m/s

x₁ = 100  #m
t₁ = x₁/u #s

50.0

The class D dispersion parameters⁴ are:

⁴ AIChE/CCPS, Guidelines for Consequence Analysis of Chemical Releases, 90.

# class D puff dispersion

σx(x) = 0.06*x^0.92
σy(x) = σx(x)
σz(x) = 0.15*x^0.70

σz (generic function with 1 method)

The release, at the point of interest, meets neither the criteria for a puff model nor a plume model.

u*Δt < 2*σx(x₁)

false

u*Δt > 5*σx(x₁)

false

So some other kind of model must be used.

Single Gaussian puff

Recall that a single Gaussian puff is the product of 3 Gaussian distributions

$c (x, y, z, t) = m Δ t \cdot g_{x} (x, t) \cdot g_{y} (y) \cdot g_{z} (z)$

with

$g_{x} (x, t) = \frac{1}{\sqrt{2 π} σ_{x}} \exp (- \frac{1}{2} {(\frac{x - u t}{σ_{x}})}^{2})$

$g_{y} (y) = \frac{1}{\sqrt{2 π} σ_{y}} \exp (- \frac{1}{2} {(\frac{y}{σ_{y}})}^{2})$

$g_{z} (z) = \frac{1}{\sqrt{2 π} σ_{z}} [\exp (- \frac{1}{2} {(\frac{z - h}{σ_{z}})}^{2}) + \exp (- \frac{1}{2} {(\frac{z + h}{σ_{z}})}^{2})]$

where, for the sake of clarity, I’ve neglected the fact that the dispersion parameters σ are themselves all functions of t by being functions of the location of the center of the puff.

gx(x, t) = exp((-1/2)*((x-u*t)/σx(u*t))^2)/(√(2π)*σx(u*t))
gy(y, t) = exp((-1/2)*(y/σy(u*t))^2)/(√(2π)*σy(u*t))
gz(z, t) = (exp((-1/2)*((z-h)/σz(u*t))^2)+exp((-1/2)*((z+h)/σz(u*t))^2))/(√(2π)*σz(u*t))

c_pf(x,y,z,t; m, Δt) = m*Δt*gx(x,t)*gy(y,t)*gz(z,t)

For some context we can plot the puff as a single, instantaneous, release

Figure 1: The dispersion of a single, instantaneous, puff.

Multiple puffs

Our first approximation to a release of appreciable duration is to break the release up into n intervals and release a single puff per interval.

$c (x, y, z, t) = \sum_{i = 0}^{n} m \frac{Δ t}{n} \cdot g_{x} (x, t - \frac{i}{n} Δ t) \cdot g_{y} (y) \cdot g_{z} (z)$

where we have simply taken the sum of n single puffs, each representing a fraction of the overall release, and emitting them one after the other.

function sum_of_puffs(x,y,z,t; m, Δt, n)
    c = 0
    δt = Δt/n
    for i in 0:1:n
        t′ = t-i*δt
        c′  = t′>0 ? c_pf(x,y,z,t′; m=m, Δt=δt) : 0
        c += isnan(c′) ? 0 : c′ 
    end
    return c
end

We can plot this for n=5 and we see that, while initially the individual puffs are distinct, they quickly merge into a larger more spread-out cloud.⁵

⁵ To an extent this is a function of using a class D atmosphere. For a much more stable atmosphere, e.g. class F, the puffs remain quite distinct until a size-able number of them have been released.

Figure 2: The dispersion of a sequence of multiple smaller puffs.

If we plot the max-concentration experienced at our point of interest, x=100m, against an increasingly finely-divided release (more puffs, but each puff represents a smaller slice of time) it is clear that they are converging towards a number, and relatively quickly.

Figure 3: The effect of increasing the number of puffs

This suggests a next step, taking the limit as $n \to \infty$

Integrated puffs

Returning to our model of multiple puffs

$c (x, y, z, t) = \sum_{i = 0}^{n} m \frac{Δ t}{n} \cdot g_{x} (x, t - \frac{i}{n} Δ t) \cdot g_{y} (y) \cdot g_{z} (z)$

We can re-arrange this and take the limit as $n \to \infty$

$c (x, y, z, t) = m \cdot g_{y} (y) \cdot g_{z} (z) \cdot (lim_{n \to \infty} \sum_{i = 0}^{n} g_{x} (x, t - \frac{i}{n} Δ t) \frac{Δ t}{n})$

$= m \cdot g_{y} (y) \cdot g_{z} (z) \cdot \int_{t - Δ t}^{t} g_{x} (x, t^{'}) d t^{'}$

Where we have replaced the limit with the integral.⁶

⁶ I am assuming the dispersion parameters are constants, though they are not in practice as they are correlated to the downwind distance to the center of any given puff. I am assuming for a small enough release this is approximately constant at least.

This is an integral of a Gaussian, and so we expect the results to be in terms of the error function

$\erf (x) = \frac{2}{\sqrt{π}} \int_{0}^{x} \exp (- t^{2}) d t$

For the integral of the x component of the Gaussian puff we have

$\int_{t - Δ t}^{t} g_{x} (x, t^{'}) d t^{'} = \int_{t - Δ t}^{t} \frac{1}{\sqrt{2 π} σ_{x}} \exp (- \frac{1}{2} {(\frac{x - u t^{'}}{σ_{x}})}^{2}) d t^{'}$

making the substitution $ξ = \frac{x - u t^{'}}{\sqrt{2} σ_{x}}$

we get⁷

⁷ This model and the sum of puffs model both naively include contributions from releases that haven’t happened yet, e.g. at t=1 only the contribution of material released at times t≤1 should be included, but without any correction the other parts of the release would be included causing slight errors in the vicinity of the release point at t<Δt. The solution is simply to take the duration of the release to be the minimum of either the elapsed time (i.e. when the release is still “happening”) or the total release duration.

$\int_{t - Δ t}^{t} g_{x} (x, t^{'}) d t^{'} = \frac{- 1}{\sqrt{π} u} \int_{a}^{b} \exp (- ξ^{2}) d ξ$

$= \frac{- 1}{\sqrt{π} u} [\frac{\sqrt{π}}{2} \erf (b) - \frac{\sqrt{π}}{2} \erf (a)]$

$= \frac{1}{2 u} (\erf (a) - \erf (b))$

where

$a = \frac{x - u (t - Δ t)}{\sqrt{2} σ_{x}}$

$b = \frac{x - u t}{\sqrt{2} σ_{x}}$

using SpecialFunctions: erf

function ∫gx(x,t,Δt)
    Δt = min(t,Δt)
    a  = (x-u*(t-Δt))/(√2*σx(u*(t-Δt)))
    b  = (x-u*t)/(√2*σx(u*t))
    return erf(b,a)/(2u)
end

intpuff(x,y,z,t; m, Δt) = m*gy(y,x/u)*gz(z,x/u)*∫gx(x,t,Δt)

Figure 4: The dispersion of the integrated puff model, assuming constant dispersion/

This release model has some convenient properties: clearly as $Δ t \to 0$ it becomes a Gaussian puff again, but also as $Δ t \to \infty$ also limits to the Gaussian plume.⁸

⁸ This is somewhat hand-wavy but a release of infinite duration is an event that began an infinite amount of time in the past and continues an infinite amount into the future, so the term $\frac{1}{2 u} (\erf (a) - \erf (b))$ goes in the limit to $\frac{1}{2 u} (\erf (\infty) - \erf (- \infty)) = \frac{1}{u}$ resulting in a concentration profile of $c (x, y, z, t) = \frac{m}{u} \cdot g_{y} (y) \cdot g_{z} (z)$ , which is exactly a plume model.

Figure 5: The limiting behaviour of the integrated puff model, it smoothly connects the single puff model and the plume model when using the same dispersion constants.

Complications

I’ve been casually treating the dispersion parameters, $σ_{x}, σ_{y}, σ_{z}$ , as being constants that are independent of the model and any transformations on the model. Within the context of taking sums and doing integrals it is reasonable: within a reasonable radius of the center of a given puff they are nearly constant. However, in practice, they depend upon time through their dependence on the location of the puff center and are also functions of the model itself.

The dispersion parameters for a plume model are not the same as for a puff, and so the nice smooth curve connecting the two doesn’t really work. Not if you are strictly taking dispersion parameters as provided in standard references. It is not at all clear how to transition from the one set to the other either, in a smooth manner, to ensure that there is a smooth transition from puff to plume.

That said, multiple puff models use the dispersion parameters for puffs and so using the puff parameters in the integrated puff model at least puts one in good company.

Update

There is a follow-up post that discusses the quality of these approximations in more detail.

When I first wrote this post I could not find my final result in the literature – it wasn’t in the standard references I use, and I think I just didn’t know the right search terms. Though it seemed equally obvious to me that it must be in the literature somewhere. Since posting this, I found it: Palazzi et al.⁹ This is also the model used by ALOHA and the older ARCHIE models.

⁹ “Diffusion from a Steady Source of Short Duration.”

References

AIChE/CCPS. Guidelines for Consequence Analysis of Chemical Releases. New York: American Institute of Chemical Engineers, 1999.

Lees, Frank P. Loss Prevention in the Process Industries. 2nd ed. Oxford: Butterworth-Heinemann, 1996.

Palazzi, E, M De Faveri, Giuseppe Fumarola, and G Ferraiolo. “Diffusion from a Steady Source of Short Duration.” Atmospheric Environment 16, no. 12 (1982): 2785–90. https://www.researchgate.net/publication/328744668_DIFFUSION_FROM_A_STEADY_SOURCE_OF_SHORT_DURATION.